Import('env buildmodule cc')

myenv = env.Clone(CPPPATH = '#include')
pyenv = myenv.Clone()
if env['PLATFORM'] == 'win32':
	import sys
	pythonver = '%c%c' % (sys.version[0], sys.version[2])
	pythonlib = 'python'+pythonver
	pythonpath = [env['pythonpath'],
		'C:\\Program Files\\Python'+pythonver]
	pyenv.Append(LIBS=pythonlib)
	pyenv.Append(CPPPATH=[s+'\\include' for s in pythonpath])
	pyenv.Append(LIBPATH=[s+'\\libs' for s in pythonpath])
	pyenv.Replace(SHLIBSUFFIX='.pyd')
else:
	pyenv.ParseConfig('python-config --includes --libs')

sources = [
	'raytracer.cc', 'scene.cc', 'shapes.cc', 'sampler.cc',
	'container.cc', 'kdtree.cc', 'octree.cc', 'material.cc',
	'serialize.cc', 'pixmap.cc']

objs = []
shared_objs = []
for src in sources:
	objs.append( myenv.Object(src) )
	shared_objs.append( myenv.SharedObject(src) )

if buildmodule:
	if cc == 'gcc':
		ccflags = '$CCFLAGS -Wno-write-strings'
	else:
		ccflags = '$CCFLAGS'
	pymodule = pyenv.SharedLibrary('pyrit',
		['raytracermodule.cc']+shared_objs,
		SHLIBPREFIX = '', CCFLAGS = ccflags)
	env.Alias('shared-objs', shared_objs)
	env.Alias('python-module', pymodule)
	Return('pymodule')
else:
	lib = myenv.StaticLibrary('pyrit', objs)
	env.Alias('objs', objs)
	env.Alias('static-lib', lib)
	Return('lib')
