Import('env pyenv buildmodule cc')

sources = [
	'common.cc', 'raytracer.cc', 'sampler.cc', 'scene.cc',
	'shapes.cc', 'material.cc', 'pixmap.cc', 'serialize.cc',
	'container.cc', 'kdtree.cc', 'octree.cc']

if buildmodule:
	shared_objs = []
	for src in sources:
		shared_objs.append( pyenv.SharedObject(src) )
	if cc == 'gcc':
		ccflags = '$CCFLAGS -Wno-write-strings'
	else:
		ccflags = '$CCFLAGS'
	if cc == 'msvc':
		linkflags = '$LINKFLAGS /export:initpyrit'
	else:
		linkflags = '$LINKFLAGS'
	pymodule = pyenv.SharedLibrary('pyrit',
		['raytracermodule.cc']+shared_objs,
		SHLIBPREFIX = '', CCFLAGS = ccflags,
		LINKFLAGS=linkflags)
	if cc == 'msvc':	
		pyenv.AddPostAction(pymodule, 'mt /nologo /manifest ${TARGET}.manifest /outputresource:$TARGET;2')
	env.Alias('shared-objs', shared_objs)
	env.Alias('python-module', pymodule)
	Return('pymodule')
else:
	objs = []
	for src in sources:
		objs.append( env.Object(src) )
	lib = env.StaticLibrary('pyrit', objs)
	env.Alias('objs', objs)
	env.Alias('static-lib', lib)
	Return('lib')